ORACLE GRAPH DB SPARQL TEST FORM





2020年国勢調査の全自治体の人口データが格納されています。詳しくはこちらをご覧ください。

トリプル数を数える

SELECT (COUNT(?s) AS ?count)
{ ?s ?p ?o .}

主語 K202000000619 の情報一覧
(2020年国勢調査/札幌市/男女総数/年齢総数/国籍総数)

PREFIX : <https://www.mirko.jp/pyramid/data/>
SELECT *
WHERE { :K202000000619 ?p ?o } 

2020年国勢調査/神奈川県/日本人のみ/女性/35歳 の人口

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#>
PREFIX cd-dimension: <http://data.e-stat.go.jp/lod/ontology/crossDomain/dimension/>
PREFIX g00200521-code-2010: <http://data.e-stat.go.jp/lod/ontology/g00200521/code/2010/>
PREFIX cd-code: <http://data.e-stat.go.jp/lod/ontology/crossDomain/code/>
PREFIX sacs: <http://data.e-stat.go.jp/lod/terms/sacs#>
PREFIX estat-measure: <http://data.e-stat.go.jp/lod/ontology/measure/>
SELECT ?population
WHERE {
 ?s cd-dimension:timePeriod "2020"^^xsd:gYear ;
    sdmx-dimension:refArea  "神奈川県"@ja ;
    cd-dimension:nationality  cd-code:nationality-japan ;
    cd-dimension:sex  cd-code:sex-female ;
    cd-dimension:age  cd-code:age-35 ;
    estat-measure:population ?population .
}

2020年国勢調査/全国+各都道府県/国籍総数/男性/年齢総数 の人口を、自治体コード順に並べる

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#>
PREFIX cd-dimension: <http://data.e-stat.go.jp/lod/ontology/crossDomain/dimension/>
PREFIX g00200521-code-2010: <http://data.e-stat.go.jp/lod/ontology/g00200521/code/2010/>
PREFIX cd-code: <http://data.e-stat.go.jp/lod/ontology/crossDomain/code/>
PREFIX sacs: <http://data.e-stat.go.jp/lod/terms/sacs#>
PREFIX estat-measure: <http://data.e-stat.go.jp/lod/ontology/measure/>
PREFIX dcterms: <http://purl.org/dc/terms/>
SELECT ?areacode ?areaname ?population
WHERE {
 ?s cd-dimension:timePeriod "2020"^^xsd:gYear ;
    cd-dimension:nationality  cd-code:nationality-all ;
    cd-dimension:sex  cd-code:sex-male ;
    cd-dimension:age  cd-code:age-all ;
    dcterms:identifier  ?areacode ;
    dcterms:isPartOf  "-" ;
    sdmx-dimension:refArea  ?areaname ;
    estat-measure:population ?population .
} 
ORDER BY ?areacode

2020年国勢調査/京都市左京区/国籍総数/男女総数 の年齢別人口

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#>
PREFIX cd-dimension: <http://data.e-stat.go.jp/lod/ontology/crossDomain/dimension/>
PREFIX g00200521-code-2010: <http://data.e-stat.go.jp/lod/ontology/g00200521/code/2010/>
PREFIX cd-code: <http://data.e-stat.go.jp/lod/ontology/crossDomain/code/>
PREFIX sacs: <http://data.e-stat.go.jp/lod/terms/sacs#>
PREFIX estat-measure: <http://data.e-stat.go.jp/lod/ontology/measure/>
PREFIX dcterms: <http://purl.org/dc/terms/>
SELECT ?age ?population
WHERE {
 ?s cd-dimension:timePeriod "2020"^^xsd:gYear ;
    sdmx-dimension:refArea  "京都市左京区"@ja ;
    cd-dimension:nationality  cd-code:nationality-all ;
    cd-dimension:sex  cd-code:sex-all ;
    cd-dimension:age ?age ;
    dcterms:identifier  ?areacode ;
    estat-measure:population ?population .
} 
ORDER BY ?s

2020年国勢調査/市区町村の人口ランキング

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#>
PREFIX cd-dimension: <http://data.e-stat.go.jp/lod/ontology/crossDomain/dimension/>
PREFIX g00200521-code-2010: <http://data.e-stat.go.jp/lod/ontology/g00200521/code/2010/>
PREFIX cd-code: <http://data.e-stat.go.jp/lod/ontology/crossDomain/code/>
PREFIX sacs: <http://data.e-stat.go.jp/lod/terms/sacs#>
PREFIX estat-measure: <http://data.e-stat.go.jp/lod/ontology/measure/>
PREFIX dcterms: <http://purl.org/dc/terms/>
SELECT ?areaname ?population
WHERE {
 ?s cd-dimension:timePeriod "2020"^^xsd:gYear ;
    cd-dimension:nationality  cd-code:nationality-all ;
    cd-dimension:sex  cd-code:sex-all ;
    cd-dimension:age  cd-code:age-all ;
    sdmx-dimension:refArea  ?areaname ;
    estat-measure:population ?population .
    MINUS {?s dcterms:isPartOf  "-" . }
} 
ORDER BY DESC (?population)
LIMIT 100

PREFIX 一覧

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dcat: <http://www.w3.org/ns/dcat#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX cc: <http://creativecommons.org/ns#>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX qb: <http://purl.org/linked-data/cube#>
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#>
PREFIX estat-measure: <http://data.e-stat.go.jp/lod/ontology/measure/>
PREFIX estat-attribute: <http://data.e-stat.go.jp/lod/ontology/attribute/>
PREFIX estat-attribute-code: <http://data.e-stat.go.jp/lod/ontology/attribute/code/>
PREFIX cd-dimension: <http://data.e-stat.go.jp/lod/ontology/crossDomain/dimension/>
PREFIX cd-code: <http://data.e-stat.go.jp/lod/ontology/crossDomain/code/>
PREFIX g00200521-dimension-2010: <http://data.e-stat.go.jp/lod/ontology/g00200521/dimension/2010/>
PREFIX g00200521-code-2010: <http://data.e-stat.go.jp/lod/ontology/g00200521/code/2010/>
PREFIX sacs: <http://data.e-stat.go.jp/lod/terms/sacs#>